Excel VBA 收费结算模块/一步一步带你设计【收费管理系统】08

本文于2023年5月25日首发于本人同名公众号：Excel活学活用，更多文章案例请搜索关注！

☆本期内容概要☆

• 用户窗体设置：收费结算模块设置（3）
• TreeView控件的使用
• Excel VBA 操作ACCESS数据库表，SQL查询语句。

大家好，我是冷水泡茶，前期我们分享了【收费管理系统】收费结算模块的设计【Excel VBA 收费结算模块/一步一步带你设计【收费管理系统】07】，没有做完，本期我们继续开干。

今天主要完成收费项目的选择输入。我们先看一下效果：

下面我们一起来看制作过程：

1、增加一个用户窗体Usf_ItemSelect，在上面增加命令按钮CmdUnfold（展开），CmdFold（折叠），CmdSearch（搜索），一个文本框TextBox1，一个TreeView控件TreeView1。

在MyModule顶端定义一个Public 变量ItemFullName用来存储与传递项目全称的值，在我们选择收费项目的时候，会把包含Inkedit1中的内容标红：Public ItemFullName As String

2、其他代码我们一起来看：

（1）UserForm_Activate()，Usf_ItemSelect 窗体启动代码，主要是以树形结构显示收费项目，供选择录入：

Private Sub UserForm_Activate()
    On Error Resume Next
    ThisWorkbook.Activate
    dataFile = ThisWorkbook.Path & "\收费管理系统数据库.accdb"
    Me.Caption = "【模块：" & Me.Caption & "】【用户：" _
        & currUserName & "】"
    '添加顶级节点
    Set Nodx = Me.TreeView1.Nodes.Add(, , "Item", "收费项目列表")
    '检查tb收费项目表有无数据
    SQL = "select count(*) from tb收费项目"
    If RecordValue(dataFile, SQL) = 0 Then
        MsgBox "没有收费项目，请先维护后再操作！"
        Exit Sub
    End If
    '添加收费项目分类节点
    SQL = "select Distinct 项目分类码,项目分类 from tb收费项目 Where 使用状态 <> '封存' Order By 项目分类码 "
    aData = GetData(dataFile, SQL)
    iRow = UBound(aData, 2)
    For i = 0 To iRow
        Set Nodx = Me.TreeView1.Nodes.Add("Item", tvwChild, aData(0, i), aData(1, i))
    Next
    '添加收费项目明细节点
    SQL = "select 上级代码,上级名称,项目代码,项目全称 from tb收费项目 Where 使用状态 <> '封存'  Order By 项目代码 "
    aData = GetData(dataFile, SQL)
    iRow = UBound(aData, 2)
    For i = 0 To iRow
        Set Nodx = Me.TreeView1.Nodes.Add(aData(0, i), tvwChild, aData(2, i), aData(3, i))
    Next
    For i = Me.TreeView1.Nodes.Count To 1 Step -1
        If Len(Me.TreeView1.Nodes(i).Key) = 4 Then
            Me.TreeView1.Nodes(i).EnsureVisible
        End If
        If Me.TreeView1.Nodes(i).Children = 0 Then
            Me.TreeView1.Nodes(i).ForeColor = vbBlue
        End If
        If InStr(Me.TreeView1.Nodes(i).Text, ItemFullName) > 0 And ItemFullName <> "" Then
            Me.TreeView1.Nodes(i).EnsureVisible
            Me.TreeView1.Nodes(i).ForeColor = vbRed
        End If
    Next
    Me.CmdFold.Left = Me.CmdUnfold.Left
    Me.CmdFold.Top = Me.CmdUnfold.Top
    Me.CmdFold.Visible = False
End Sub

代码解析：

（A）首先我们添加一个顶级节点“Item”

Set Nodx = Me.TreeView1.Nodes.Add(, , "Item", "收费项目列表")

TreeView添加节点语法：（节点，关系，本节点KEY，本节点TEXT），由于是顶级节点，前面两个参数留空。待到继续增加子节点时，它的参数是这样的：

（父节点KEY,tvwChild,本节点KEY，本节点TEXT）

这里要注意，Key不能以数字开头，还区分大小写，节点不能重复添加，在添加本节点时，确保父节点已添加。

（B）接着添加一个项目分类的二级节点，数据可以取自“tb收费项目分类”，也可以取自“tb收费项目”，前者容易出现仅有项目分类而没有明细收费项目的节点，给输入造成不便，这里我们选择后者。

'添加收费项目分类节点
SQL = "select Distinct 项目分类码,项目分类 from tb收费项目 Where 使用状态 <> '封存' Order By 项目分类码 "
aData = GetData(dataFile, SQL)
iRow = UBound(aData, 2)
For i = 0 To iRow
    Set Nodx = Me.TreeView1.Nodes.Add("Item", tvwChild, aData(0, i), aData(1, i))
Next

（C）然后我们添加明细收费项目节点，这里SQL语句一定要按照项目代码排序，确保父节点在前面。

（D）接下来，对节点的显示做一些优化

（a）窗体启动时，TreeView不完全显示，显示到代码长度=4的节点，余下不显示。

（b）末级节点显示为蓝色。

（c）包含InkEdit1控件内容的节点，显示为红色

（E）最后，对展开、折叠节点的两个按钮位置进行调整，在窗体启动后，我们只看到展开按钮，就是那个加号。

（3）节点展开折叠按钮：

Private Sub CmdUnfold_Click()
    For i = Me.TreeView1.Nodes.Count To 1 Step -1
        Me.TreeView1.Nodes(i).EnsureVisible
    Next
    Me.CmdFold.Visible = True
    Me.CmdUnfold.Visible = False
End Sub
Private Sub CmdFold_Click()
    For Each n In TreeView1.Nodes
        If Len(n.Key) = 2 Then
            n.Expanded = False
        End If
    Next
    Me.CmdFold.Visible = False
    Me.CmdUnfold.Visible = True
End Sub

代码解析：

点展开（+），从最后一个节点开始循环显示，展开按钮隐藏，折叠按钮（-）显示。

点折叠（-），循环所有节点，把key长度=2的节点的Expanded值设为False，展开按钮（+）显示。

（4）节点点击事件代码：

Private Sub TreeView1_NodeClick(ByVal Node As MSComctlLib.Node)
    On Error Resume Next
    If Me.TreeView1.SelectedItem.Children = 0 Then
        If IsFormActive("Usf_AddAndModify") Then
            With Usf_AddAndModify
                .InkEdit1.Text = Me.TreeView1.SelectedItem.Text
            End With
        End If
        Unload Me
    End If
End Sub

代码解析：

把末级节点的Text赋值给InkEdit1，窗体退出。

（5）修改InkEdit控件的Db_Click事件代码：

ElseIf currTable = "tb收费明细" Then '收费明细
    If .ColumnHeaders(intCol) = "收费项目" Then
        ItemFullName = InkEdit1
        Usf_ItemSelect.Show
    End If
End If

代码解析：

如果currTable = "tb收费明细" ，如果双击的栏目表头是“收费项目”，那么我们把Inkedit1的值传递给ItemFullName，然后显示Usf_ItemSelect窗体（完）。

最近比较忙，就先做到这吧，请大家见谅。后面会继续，敬请关注！还请大家多多点赞、留言、分享，谢谢大家，我们下期再会。

☆猜你喜欢☆

本文于2023年5月25日首发于本人同名公众号：Excel活学活用，更多文章案例请搜索关注！